components/mus/gles2/BUILD.gn

# Copyright 2014 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/ui.gni")

source_set("gles2") {
  visibility = [
    "//components/mus:*",
    "//components/mus/ws:*",
    "//components/mus/surfaces:*",
    "//services/shell/standalone:lib",  # For android
  ]

  sources = [
    "command_buffer_driver.cc",
    "command_buffer_driver.h",
    "command_buffer_driver_manager.cc",
    "command_buffer_driver_manager.h",
    "command_buffer_impl.cc",
    "command_buffer_impl.h",
    "command_buffer_local.cc",
    "command_buffer_local.h",
    "command_buffer_local_client.h",
    "command_buffer_task_runner.cc",
    "command_buffer_task_runner.h",
    "gl_surface_adapter.cc",
    "gl_surface_adapter.h",
    "gpu_impl.cc",
    "gpu_impl.h",
    "gpu_memory_tracker.cc",
    "gpu_memory_tracker.h",
    "gpu_state.cc",
    "gpu_state.h",
  ]

  public_deps = [
    ":lib",
  ]
  deps = [
    "//base",
    "//components/mus/public/interfaces",
    "//gpu/command_buffer/client",
    "//gpu/command_buffer/client:gles2_interface",
    "//gpu/command_buffer/common:gles2_utils",
    "//gpu/command_buffer/service",
    "//gpu/config:config",
    "//mojo/converters/geometry",
    "//mojo/public/cpp/bindings",
    "//ui/gfx",
    "//ui/gfx/geometry",
    "//ui/gl",
    "//ui/gl/init",
    "//ui/mojo/geometry:interfaces",
  ]

  if (is_android) {
    deps += [ "//mojo/platform_handle:platform_handle_impl" ]
  } else {
    deps += [ "//mojo/platform_handle" ]
  }

  if (use_ozone) {
    deps += [ "//ui/ozone:ozone" ]
    sources += [
      "ozone_gpu_memory_buffer.cc",
      "ozone_gpu_memory_buffer.h",
    ]
  }

  include_dirs = [ "../.." ]
}

source_set("lib") {
  sources = [
    "command_buffer_type_conversions.cc",
    "command_buffer_type_conversions.h",
    "gpu_memory_buffer_impl.cc",
    "gpu_memory_buffer_impl.h",
    "mojo_buffer_backing.cc",
    "mojo_buffer_backing.h",
    "mojo_gpu_memory_buffer.cc",
    "mojo_gpu_memory_buffer.h",
    "mojo_gpu_memory_buffer_manager.cc",
    "mojo_gpu_memory_buffer_manager.h",
    "raster_thread_helper.cc",
    "raster_thread_helper.h",
  ]

  deps = [
    "//base",
    "//cc",
    "//components/mus/public/interfaces",
    "//gpu/command_buffer/client",
    "//gpu/command_buffer/common",
    "//gpu/config:config",
    "//mojo/public/cpp/bindings",
    "//mojo/public/cpp/system",
    "//ui/gfx",
    "//ui/gfx/geometry",
  ]

  include_dirs = [ "../.." ]
}